내용
기초
접속 만들기
옵션들
SQL 사용하기
중급
SELECT statements
고급
Transactions
주의
Other Resources
이문서의 목적은 Perl DBI modules을 이용한 데이터베이스 접근에 대한 예제를 제공하는 것이다. 이것을 작성하게 된 이유는 DBI mailing list에 너무 많은 트래픽이 걸리기 때문이다.
이 문서대로 진행하면 DBI를 이용하여 오라클 데이타베이스로 접근하는 방식을 배우게 될 것이다. DBI 기초로 부터 시작하여 성능과 신뢰성을 향상시키는 방향으로 진행하게 될것이다.
기초
처음으로 해야 할것은 DBI를 설치하는 일이다. 이것을 위해서 DBI INSTALL 문서를 참조하기 바란다. 이것이 다 되고 나면 database driver 또는 DBD를 설치할 필요가 있다. DBD를 설치하기 위한 설명 역시 각각의 package 내에 포함되어 있다. 대부분의 perl 모듈들처럼 DBI/DBD를 설치하는 것은 쉽고 간편하게 되어 있다.
localhost:/opt/src/perl_modules/DBI-1.02$ perl Makefile.PL && make && make test && make install
DBI와 DBD를 적절하게 설치하고 난 후, 다음과 같은 방식으로 좀더 자세한 정보를 얻을 수 있다:
localhost:~$ perldoc DBI
데이터베이스로 접속하기
데이터베이스로 접근하는 것은 데이터베이스의 종류에 따라 다른 방식을 필요로 한다. 이런 광범위한 정보는 DBD와 함께 제공되는 문서를 읽어 보기 바란다. 이 예제는 오라클로 접속하는 방법에 대해서 주로 논하게 될것이다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
);
위의 접속 문자열에는 data source name, username 그리고 password 등의 세개의 인자를 필요로 한다. DSN은 dbi:DriverName:instance의 형태로 있다. 그러나 접속이 성공했는지 안했는지를 어떻게 알것인가? 먼저 성공했다면 connect는 참값 (true value)을 그렇지 않다면 거짓값을 돌려 줄것이다. 둘째로 DBI는 package 내에 있는 $DBI::errstr 변수에 에러 메시지를 넣어 둔다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
) || die "Database connection not made: $DBI::errstr";
$dbh->disconnect();
disconnect() method 를 이용하여 "Database handle destroyed without explicit disconnect" 에러를 피할 수 있다.
옵션들
connect() method 는 옵션 hash를 취한다. 자주 사용되는 옵션에는 다음과 같은 것들이 있다: AutoCommit, 이 값이 참이라면 데이터베이스 transaction을 자동으로 commit 하게 된다; RaiseError, 이것은 에러가 발생했을 때 DBI의 불평을 $DBI::errstr 에게 알려 준다; PrintError, 이것은 DBI가 $DBI::errstr에 경고를 넣어 준다.
이 프로그램에서, 트랜젝션을 사용할려고 한다. 그래서 AutoCommit는 off로, RaiseError는 on으로, 그리고 PrintError는 기본값으로 남겨 두었다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
$dbh->disconnect();
데이터베이스의 AutoCommit을 off로 두었다는 것을 명심해야 한다. 이것은 트랜젝션에 치명적인 오류가 발생했을 경우에는 지원하지 않는다는 것이다.
SQL 사용하기
이제 우리는 데이타베이스를 가지고 무언가 유용한 것을 할 준비가 된것이다. SQL 문을 데이터베이스에 전달하는 방법에는 두가지가 있다. SELECT와 같은 row를 돌려 주는 질의들에 대해 준비된 방식을 적용할 것이다. CREATE, DELETE와 같은 다른 질의들은 do method를 이용할 것이다. 후자를 먼저 해보고 전자는 뒤에 설명하겠다.
이 프로그램은 데이터베이스 내에 employee 라는 테이블을 만드는 것이다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
my $sql = qq{ CREATE TABLE employees ( id INTEGER NOT NULL,
name VARCHAR2(128),
title VARCHAR2(128),
phone CHAR(8)
) };
$dbh->do( $sql );
$dbh->disconnect();
중급
어떻게 데이터베이스로 접근하며, 어떻게 에러를 알아내며, 어떻게 단순한 SQL문을 실행 할것인지에 대해 보게 될 것이다. 이제 좀더 실용적인 코드를 작성해 보자.
SELECT 구문
SELECT 구문은 SQL에서 가장 많이 이용되는 문장일 것이다. SELECT를 이용하기 위하여, 먼저 구문을 준비(Prepare)하고 그것을 실행(Execute)해야 한다. 다음 코드에서 $sth는 구문 핸들(statement handle)이다. 이것은 SELECT문의 결과로 접근하고자 할 때 이용될 것이다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
my $sql = qq{ SELECT * FROM employees };
my $sth = $dbh->prepare( $sql );
$sth->execute();
$dbh->disconnect();
위에 나열된 코드는 데이터베이스가 구문에 대해 실행 계획을 세우고 그러고 나서 구문을 실행하는 것이다. 결과로 돌아온 row들을 가지고 어떤 작업을 하지는 않는다. 다음에 나열된 코드에서는 데이터베이스로 부터 나온 레코드들을 얻기 위하여 bind_columns을 사용하는 것이다. fetch가 호출되면 그것은 데이터베이스로 부터 돌아온 값들로 채워지게 된다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
my $sql = qq{ SELECT id, name, title, phone FROM employees };
my $sth = $dbh->prepare( $sql );
$sth->execute();
my( $id, $name, $title, $phone );
$sth->bind_columns( undef, \$id, \$name, \$title, \$phone );
while( $sth->fetch() ) {
print "$name, $title, $phone\n";
}
$sth->finish();
$dbh->disconnect();
이것은 회사 전화부를 출력하는 좋은 프로그램이다. 그러나 WHERE이 어떠한가? 우리는 한번 SQL 문장을 준비하기 위해 bind_param을 사용하고, 대단히 빠르게 이것을 여러번 이용했다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
my @names = ( "Larry%", "Tim%", "Randal%", "Doug%" );
my $sql = qq{ SELECT id, name, title, phone FROM employees WHERE name LIKE ? };
my $sth = $dbh->prepare( $sql );
for( @names ) {
$sth->bind_param( 1, $_, $DBI::SQL_VARCHAR );
$sth->execute();
my( $id, $name, $title, $phone );
$sth->bind_columns( undef, \$id, \$name, \$title, \$phone );
while( $sth->fetch() ) {
print "$name, $title, $phone\n";
}
}
$sth->finish();
$dbh->disconnect();
고급
Transactions
이제까지 트랜잭션을 요하는 것은 다루어 보지 않았다. 만약 UPDATE 또는 DELETE 문장을 실행할 필요가 있다면 트랜젝션을 사용해야 한다. DBI 문서에 따르면, DBI를 이용하여 견고한 트랜젝션을 구현할려면 에러를 잡아내기 위해서 eval{...} blocks을 사용해야 하며, 종료할 때 commit이나 rollback을 이용한다. 다음 코드에서 예제를 보여주고 있다.
이 프로그램은 네개의 레코드를 데이터베이스로 올리는 것이다.
use strict;
use DBI;
my $dbh = DBI->connect( 'dbi:Oracle:orcl',
'jeffrey',
'jeffspassword',
{
RaiseError => 1,
AutoCommit => 0
}
) || die "Database connection not made: $DBI::errstr";
my @records = (
[ 0, "Larry Wall", "Perl Author", "555-0101" ],
[ 1, "Tim Bunce", "DBI Author", "555-0202" ],
[ 2, "Randal Schwartz", "Guy at Large", "555-0303" ],
[ 3, "Doug MacEachern", "Apache Man", "555-0404" ]
);
my $sql = qq{ INSERT INTO employees VALUES ( ?, ?, ?, ? ) };
my $sth = $dbh->prepare( $sql );
for( @records ) {
eval {
$sth->bind_param( 1, @$_->[0], $DBI::SQL_INTEGER );
$sth->bind_param( 2, @$_->[1], $DBI::SQL_VARCHAR );
$sth->bind_param( 3, @$_->[2], $DBI::SQL_VARCHAR );
$sth->bind_param( 4, @$_->[3], $DBI::SQL_VARCHAR );
$sth->execute();
$dbh->commit();
};
if( $@ ) {
warn "Database error: $DBI::errstr\n";
$dbh->rollback(); #just die if rollback is failing
}
}
$sth->finish();
$dbh->disconnect();
주의
예제에서 finish를 사용하는 것은 꼭 필요한 것은 아니다. 만약 다 실행하고 나면 구문핸들 (statement handele)을 다 실행하고 나면 호출하는 것이며, 프로그램을 다 실행하고 나서 호출하는 것은 아니다.
항상 use strict.
Other Resources
DBI at Hermetica
DBI mailing list information
DBI mailing list archives
Persistent connections with mod_perl
http://database.sarang.net/database/perl/dbi-example.html#connect
|
|
